| ARPlayer:!Run
| Uniqueway Ltd, 1994
| Acorn Computers Ltd, 1994

RMEnsure UtilityModule 3.10 Error ARPlayer can only be run under RISCOS 3.1 or later

Set ARPlayer$Dir <Obey$Dir>
SetMacro ARPlayer$Path <ARPlayer$Dir>.

IconSprites ARPlayer:!Sprites

Set Alias$ARPlay Run ARPlayer:ARPlay %%*0

| ---------------------------------------------------------------
| Check ARMovie existence and version

If "<ARMovie$Dir>" = "" Then Error ARMovie resources not found. Please open a directory display containing the !ARMovie application.

WimpSlot -min 288K
@RunType_AE7 ARPlayer:Dummy -playfor 0 -noerror

RMEnsure ReplaySupport 0.28 RMLoad ARPlayer:Modules.ReplaySpt
ReplayCheckVer 0.30 Error ARPlayer requires newer resources. Please update the !ARMovie application.

| ---------------------------------------------------------------
| If the sound modules are loaded then check that we have up to date versions
| If they are not loaded then ignore until they are needed

%Set Alias$RMcheck seteval ARPlayer$eval 1|M RMEnsure %%0 0 seteval ARPlayer$eval 0|Mif ARPlayer$eval THEN RMEnsure %%0 %%1 RMLoad %%*2|M unset ARPlayer$eval

RmCheck SoundFile 0.18 ARPlayer:Modules.SoundFile
RmCheck SoundFileExtMSADPCM 0.03 ARPlayer:Modules.MSADPCM

Unset Alias$RmCheck

| ---------------------------------------------------------------
| The following system variable can be altered for your system.

| This variable sets from where to save and load the Choices file.
SetMacro ARPlayer$OptionsFile <ARPlayer$Dir>.!Choices

| This variable sets where to save an obey file to setup the Replay system variables
| The file is run either on boot up or when !ARPlayer.!Boot is run
If "<Choices$Write>" = "" Then SetMacro ARPlayer$StateFile <ARPlayer$Dir>.!State Else SetMacro ARPlayer$StateFile <Choices$Write>.Boot.PreDesk.ARPlayer

| Temporarily set the amount of memory to claim for MIDI files
Set ARPlayer$MIDIMem 100

| ---------------------------------------------------------------
| Setup slot and go

WimpSlot -min 228k
WimpSlot -min 224k -max 224K

Run ARPlayer:!RunImage %*0
